Benches Uncategorized

7

File Path

apple Verified

Imported from the Apple Support Forums via the Wayback Machine 🔗

Hi all,

Is it possible to see the path of a song or video in iTunes? Out of all the information you can select this is the one thing that seems to be missing.

7 replies

Sign in or join Beachball Help to reply.

  1. 0

    Zevoneer

    Imported from the Apple Support Forums via the Wayback Machine 🔗

    There's no file path column you can add to your library view however if you want to see the path for a particular track you can find it. Right click on the entry you are interested in and choose Get Info, from the box that open choose the Summary tab, at the bottom is a section labelled "Where" that displays the file path.

  2. 0

    Robert Jacobson1

    Imported from the Apple Support Forums via the Wayback Machine 🔗

    I wrote a script that will set the "Description" of each track in the playlist(s) you select to the file path. You then can just turn on the Description column in your iTunes view.

    WARNING: If any description for the track exists, it will be overwritten!

    Download the script here:

    http://home.comcast.net/~teridon73/itunesscripts/itunespathdescription.vbs

    The script is reproduced for reference below:


    ' ###############################################################################
    ' #
    ' # itunespathdescription.vbs
    ' #
    ' # This script set the Description of all the files in a single playlist
    ' # to the file Path.
    ' #
    ' # Copyright (C) 2008 Robert Jacobson
    ' # written by: Robert Jacobson (http://home.comcast.net/~teridon73/itunesscripts)
    ' # Last Updated: 2 Feb 2008
    ' # Version 1.0
    ' #
    ' # This script is GPL v2. see http://www.gnu.org/copyleft/gpl.html
    ' #
    ' # Change record:
    ' # 1 Script creation
    ' #
    ' ###############################################################################
    Option Explicit
    Dim iTunesApp ' iTunes.Application object used to access the iTunes application.
    Dim tracks ' The tracks collection object of the Library object.
    Dim FileList ' The list of files that have been copied.
    Dim i ' A counter variable.
    Dim Msg ' A string for a message.
    Dim f ' A file object.
    Dim sources
    Dim source
    Dim playlists
    Dim playlist
    Dim playlistName
    Dim j
    Dim m
    Dim songName
    Dim artist
    Dim result
    Dim listarray
    Dim num
    Dim k
    Dim track
    Dim numtracks
    Set iTunesApp = CreateObject("iTunes.Application.1")
    Set sources = iTunesApp.Sources
    DIM use_windows
    Dim Playlist_list
    'detect CSCRIPT context & use InputLine
    IF Instr(lcase(wscript.FullName), "cscript")>0 THEN
    use_windows = 0
    ELSE 'detect WSCRIPT context & use native InputBox
    use_windows = 1
    END IF
    For i = 1 to sources.Count
    Set source = sources.Item(i)

    IF source.Kind = 1 Then
    Set playlists = source.Playlists
    if use_windows = 0 Then
    For j = 1 to playlists.Count
    Set playlist = playlists.Item(j)
    playlistName = playlist.Name
    Wscript.Echo j & ": " & playlistName
    Next
    Else
    For j = 1 to playlists.Count
    Set playlist = playlists.Item(j)
    playlistName = playlist.Name
    Playlist_list = Playlist_list & j & ": " & playlistName & Chr(10)
    Next
    End if

    If use_windows = 0 Then
    Wscript.Echo ""
    Wscript.StdOut.Write "Enter comma-separated lists to process: "
    result = Wscript.StdIn.ReadLine
    Else
    result = InputBox(Playlist_list & Chr(10) & "Enter comma-separated lists to process: ", "Which Playlist(s)")
    End if


    listarray = split(result, ",")
    For k = 0 to UBound(listarray)
    num = listarray(k)
    Set playlist = playlists.Item(num)
    playlistName = playlist.Name
    If use_windows = 0 Then
    Wscript.Echo ""
    Wscript.Echo chr(9) & "Processing playlist " & num & ": " & playlistName
    End If

    Set tracks = playlist.Tracks
    numtracks = tracks.Count
    If use_windows = 0 Then
    Wscript.Echo chr(9) & "tracks: " & numtracks
    End If
    For m = numtracks to 1 step -1
    'If m > tracks.Count Then Exit For
    Set track = tracks.Item(m)
    'Wscript.Echo "num: " & numtracks & " Count: " & tracks.Count & " m: " & m

    If track.Kind = 1 Then
    FileList = track.Location
    track.Description = FileList
    End If
    Next
    If use_windows = 0 Then
    Wscript.Echo "Finished processing playlist " & playlistName
    End If
    Next

    'End If
    End If
    Next

  3. 0

    wschloss42

    Imported from the Apple Support Forums via the Wayback Machine 🔗

    In what file or folder do i put this script?

  4. 0

    wschloss42

    Imported from the Apple Support Forums via the Wayback Machine 🔗

    In what file or folder do i put this script?

  5. 0

    cyon

    Imported from the Apple Support Forums via the Wayback Machine 🔗

    Hello Robert, i would really appreciate if you could explain how i can make this script run in WinXP Pro. I have been looking for this function for years, im so glad someone (you) has written a script, i just dont know how to use it...

    I have checked your website and downloaded your scripts pack but this particualr one isn't listed in your UI, so im lost. Also your link you posted on this thread is down. Any help is well appreciated, which you will see in your paypal account in due course.

    Many thanks

    Cyon

  6. 0

    Blipit

    Imported from the Apple Support Forums via the Wayback Machine 🔗

    That, my friend is a piece of magic. If I'd known just how feature poor iTunes was, I'd not have purchased this new Touch...oh well.

  7. 0

    Robert Jacobson1

    Imported from the Apple Support Forums via the Wayback Machine 🔗

    New link:

    http://www.pobox.com/~teridon/itunesscripts/itunespathdescription.vbs

    You can save the script anywhere, it doesn't matter, as long as you can FIND it!